sonarqube/settings.gradle at master · SonarSource/sonarqube · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
pluginManagement {
  repositories {
    def artifactoryPassword = System.env.'ARTIFACTORY_ACCESS_TOKEN'

    maven {
      if (artifactoryPassword) {
        url 'https://repox.jfrog.io/repox/plugins.gradle.org/'
        authentication {
          header(HttpHeaderAuthentication)
        }
        credentials(HttpHeaderCredentials) {
          name = "Authorization"
          value = "Bearer $artifactoryPassword"
        }
      } else {
        url 'https://plugins.gradle.org/m2/'
      }
    }
  }
}
plugins {
  id("com.gradle.develocity") version("4.3.2")
  id("com.gradle.common-custom-user-data-gradle-plugin") version "2.4.0"
}

rootProject.name = 'sonarqube'

include 'plugins:sonar-xoo-plugin'
include 'plugins:sonar-education-plugin'

include 'server:sonar-auth-common'
include 'server:sonar-auth-bitbucket'
include 'server:sonar-auth-github'
include 'server:sonar-auth-gitlab'
include 'server:sonar-auth-ldap'
include 'server:sonar-auth-saml'
include 'server:sonar-ce'
include 'server:sonar-ce-common'
include 'server:sonar-ce-task'
include 'server:sonar-ce-task-projectanalysis'
include 'server:sonar-db-dao'
include 'server:sonar-db-migration'
include 'server:sonar-db-profiling'
include 'server:sonar-main'
include 'server:sonar-process'
include 'server:sonar-server-common'
include 'server:sonar-statemachine'
include 'server:sonar-telemetry'
include 'server:sonar-telemetry-core'
include 'server:sonar-webserver'
include 'server:sonar-webserver-api'
include 'server:sonar-webserver-auth'
include 'server:sonar-webserver-common'
include 'server:sonar-webserver-core'
include 'server:sonar-webserver-es'
include 'server:sonar-webserver-webapi'
include 'server:sonar-webserver-webapi-v2'
include 'server:sonar-webserver-pushapi'
include 'server:sonar-webserver-ws'
include 'server:sonar-alm-client'
include 'server:sonar-webserver-monitoring'

include 'sonar-application'
include 'sonar-core'
include 'sonar-sarif'
include 'sonar-duplications'
include 'sonar-markdown'
include 'sonar-plugin-api-impl'
include 'sonar-scanner-engine'
include 'sonar-scanner-engine-shaded'
include 'sonar-scanner-protocol'
include 'sonar-shutdowner'
include 'sonar-testing-harness'
include 'sonar-testing-ldap'
include 'sonar-ws'
include 'sonar-ws-generator'

// Use local organizations build instead of published artifacts from Artifactory
// Set useLocalOrg=true in ~/.gradle/gradle.properties
// Requires SONARQUBE_UNIFICATION_PATH environment variable pointing to sonarqube-unification directory
def useLocalOrg = settings.hasProperty('useLocalOrg') && settings.useLocalOrg.toBoolean()
if (useLocalOrg) {
  def orgPath = System.getenv('SONARQUBE_UNIFICATION_PATH')
  if (!orgPath) {
    throw new GradleException(
      "useLocalOrg is enabled but SONARQUBE_UNIFICATION_PATH environment variable is not set.\n" +
      "Please set it to the path of your sonarqube-unification directory:\n" +
      "  export SONARQUBE_UNIFICATION_PATH=/path/to/sonarqube-unification"
    )
  }
  def orgDir = new File(orgPath, 'organizations')
  println "Using local organizations build from: ${orgDir.absolutePath}"
  includeBuild(orgDir.absolutePath) {
    dependencySubstitution {
      substitute module("org.sonarsource.sonarqube:organizations-api") using project(':organizations-api')
      substitute module("org.sonarsource.sonarqube:organizations-server-app") using project(':organizations-server-app')
    }
  }
} else {
  println "Using published organizations artifacts from Artifactory"
}


ext.isCiServer = System.getenv().containsKey("GITHUB_ACTIONS")

develocity {
  projectId = "sonar-enterprise"
  server = "https://develocity.sonar.build"
  buildScan {
    uploadInBackground.set(!isCiServer)
    publishing.onlyIf { isCiServer && it.authenticated }
    if (isCiServer) {
      buildScan.value 'Branch', System.getenv()["GITHUB_REF_NAME"]
      buildScan.value 'GitHub Actions Run', "https://github.com/${System.getenv('GITHUB_REPOSITORY')}/actions/runs/${System.getenv('GITHUB_RUN_ID')}"
    }
  }
}

buildCache {
  local {
    enabled = !isCiServer
  }
  remote(develocity.buildCache) {
    push = isCiServer
  }
}


// use Settings.getRootDir() so that it doesn't matter which directory you are executing from
File extraSettings = new File(rootDir, 'private/private-settings.gradle')
if (extraSettings.exists()) {
  apply from: extraSettings
}